[سؤال] نقل سجل من جدول الى جدول اخر

كود :

Public Class Form1

    Dim connStr1 As String = "Provider=Microsoft.ACE.OLEDB.12.0;Data Source=Database1.accdb;"

    Dim connStr2 As String = "Provider=Microsoft.ACE.OLEDB.12.0;Data Source=Database1.accdb;"

    Dim sql1 As String = "SELECT * FROM [table1]"

    Dim sql2 As String = "SELECT * FROM [table2]"

    Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load

        DataGridView1.AllowDrop = True

        DataGridView2.AllowDrop = True

        Call fillDatagridviews()

    End Sub

    Dim dt1 As New DataTable

    Dim dt2 As New DataTable

#Region " تعبئت الجدول من قاعدت البيانات "

    Private Sub fillDatagridviews()

        Dim c1 = New OleDb.OleDbDataAdapter("SELECT * FROM [table1]", connStr1).Fill(dt1)

        DataGridView1.DataSource = dt1

        Dim c2 = New OleDb.OleDbDataAdapter("SELECT * FROM [table2]", connStr2).Fill(dt2)

        DataGridView2.DataSource = dt2

    End Sub

#End Region

#Region " تحديث قاعدت البيانات "

    Private Sub updateDatebase()

        Using da As New OleDb.OleDbDataAdapter(sql1, connStr1)

            Using builder As New OleDb.OleDbCommandBuilder(da)

                da.Update(dt1)

            End Using

        End Using

        Using da As New OleDb.OleDbDataAdapter(sql2, connStr2)

            Using builder As New OleDb.OleDbCommandBuilder(da)

                da.Update(dt2)

            End Using

        End Using

    End Sub

#End Region

    ' الطريقه الاولى

#Region " زر النقل بعد اختيار اسطر من الجدول الاول "

    Private Sub Button1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button1.Click

        For Each row As DataGridViewRow In DataGridView1.SelectedRows

            If DataGridView1.AllowUserToAddRows And row.Index = DataGridView1.Rows.Count - 1 Then Exit For

            dt2.Rows.Add((From cels In row.Cells Select cels.Value).ToArray)

            DataGridView1.Rows.Remove(row)

        Next

        DataGridView2.DataSource = dt2

    End Sub

#End Region

    ' الطريقه الثانيه

#Region " زر النقل بعد النقر المزدوج على سطر في الجدول الاول "

    Private Sub DataGridView1_RowHeaderMouseDoubleClick(ByVal sender As Object, ByVal e As System.Windows.Forms.DataGridViewCellMouseEventArgs) Handles DataGridView1.RowHeaderMouseDoubleClick

        If sender.AllowUserToAddRows And e.RowIndex = sender.Rows.Count - 1 Then Return

        dt2.Rows.Add((From cels In CType(sender, DataGridView).Rows(e.RowIndex).Cells Select cels.Value).ToArray)

        sender.Rows.Remove(sender.Rows(e.RowIndex))

        DataGridView2.DataSource = dt2

        Call updateDatebase()

    End Sub

#End Region

    ' الطر يقه الثالثه 

#Region " طريقت سحب سطر من الجدول الاول واسقاطه على الجدول الثاني "

    Private Sub DataGridView1_DragOver(ByVal sender As Object, ByVal e As DragEventArgs) Handles DataGridView1.DragOver

        e.Effect = DragDropEffects.Move

    End Sub

    Private Sub DataGridView1_MouseMove(ByVal sender As Object, ByVal e As MouseEventArgs) Handles DataGridView1.MouseMove

        If (e.Button And MouseButtons.Left) = MouseButtons.Left Then

            If sender.CurrentRow.Index = If(sender.AllowUserToAddRows, sender.Rows.Count - 1, sender.Rows.Count) Then Return

            sender.DoDragDrop(sender.Rows(sender.CurrentRow.Index), DragDropEffects.Move)

        End If

    End Sub

    Private Sub DataGridView2_DragOver(ByVal sender As Object, ByVal e As DragEventArgs) Handles DataGridView2.DragOver

        e.Effect = DragDropEffects.Move

    End Sub

    Private Sub DataGridView2_DragDrop(ByVal sender As Object, ByVal e As DragEventArgs) Handles DataGridView2.DragDrop

        If (e.Effect = DragDropEffects.Move) Then

            Dim row As DataGridViewRow = e.Data.GetData(GetType(DataGridViewRow))

            dt2.Rows.Add((From cels In row.Cells Select cels.Value).ToArray)

            DataGridView1.Rows.Remove(DataGridView1.CurrentRow)

            Call updateDatebase()

        End If

    End Sub

#End Region

End Class