منتدى فيجوال بيسك لكل العرب | منتدى المبرمجين العرب
استعلام بخصوص حقل date - نسخة قابلة للطباعة

+- منتدى فيجوال بيسك لكل العرب | منتدى المبرمجين العرب (http://vb4arb.com/vb)
+-- قسم : قسم قواعد البيانات (http://vb4arb.com/vb/forumdisplay.php?fid=40)
+--- قسم : قسم أسئلة قواعد البيانات تحت بيئة الـ.NET (http://vb4arb.com/vb/forumdisplay.php?fid=41)
+--- الموضوع : استعلام بخصوص حقل date (/showthread.php?tid=12953)

استعلام بخصوص حقل date - djelloul - 15-08-15

[attachment=7625][attachment=7624]
السلام عليكم ورحمة الله تعالى وبركاته
الأساتذة الكرام
هذه صورة لجدول به حقل خاصيته date عملت الإستعلام التالي من أجل ملأ قريد فيو الإستعلام هو :
Dim date2 As Date = Now.Date
        Rendez_VDa = New SqlDataAdapter("SELECT * From Rendez_V where Dte_RV = # " & date2.Year.ToString & "/" & date2.Month.ToString & "/" & date2.Day.ToString & " # ORDER BY Dte_RV, Hte_RV", cnn)
فظهرت لي رسالة الخطأ المتمثلة في الصورة الثانية
أرجوا منكم المساعدة

RE: استعلام بخصوص حقل date - الطالب - 15-08-15

سلام

كود :
Using da As New SqlDataAdapter("SELECT * From [Rendez_V] WHERE [Dte_RV]=@Dte_RV ORDER BY [Dte_RV], [Hte_RV]", cnn)
    da.SelectCommand.Parameters.AddWithValue("@Dte_RV", Now.Date)
    Using dt As New DataTable
        da.Fill(dt)
        DataGridView1.DataSource = dt
    End Using
End Using

موفقين

RE: استعلام بخصوص حقل date - djelloul - 15-08-15

ألف شكر لكم أخي الكريم على تفاعلكمك السريع وعلى الإجابة راح أجرب ثم أعلمكم

RE: استعلام بخصوص حقل date - Sajad - 15-08-15

السلام عليكم

موضوع مخالف

تم النقل الى قسم قواعد البيانات تحت بيئة الـNET.

سيتم حذف أي موضوع مخالف في المرة القادمة ان لم يكن في القسم المناسب

تحياتي

RE: استعلام بخصوص حقل date - djelloul - 16-08-15

الف شكر لكم أخي الكريم على المساعدة تم تجربة الكود وهو يعمل بشكل جيد بفضل الله ثم بعونكم فلكم كل الشكر والإحترام والعفو من السادة المشرفين على خطأ في القسم فمعذرة رجاءا
أخي الكريم لو أردت أن أجعل الاستعلام بين تاريخين بهذا الشكل:
Between #" & DateTimePicker1.Value & "# And #" & DateTimePicker2.Value & "#
فماذا أفعل
ألف شكر لكم

RE: استعلام بخصوص حقل date - الطالب - 16-08-15

سلام

كود :
Using da As New SqlDataAdapter("SELECT * From [Rendez_V] WHERE [Dte_RV] Between @Dte_RV_1 And @Dte_RV_2 ORDER BY [Dte_RV], [Hte_RV]", cnn)
    da.SelectCommand.Parameters.AddWithValue("@Dte_RV_1", DateTimePicker1.Value.Date)
    da.SelectCommand.Parameters.AddWithValue("@Dte_RV_2", DateTimePicker2.Value.Date)
    Using dt As New DataTable
        da.Fill(dt)
        DataGridView1.DataSource = dt
    End Using
End Using

موفقين

RE: استعلام بخصوص حقل date - djelloul - 17-08-15

الف شكر لكم أخي الكريم أدامك الله

RE: استعلام بخصوص حقل date - djelloul - 17-08-15

السلام عليكم ورحمة الله تعالى وبركاته أخي الكريم هذه الطريقة أعجبتني كثيرا خصوصا أنها تفاديك من الأخطاء ممكن أجد لديكم جميع الأوامر اي Select, Insert, Delet, Update
شكرا لكم

RE: استعلام بخصوص حقل date - الطالب - 17-08-15

سلام

هذه تفضل الاكواد

INSERT
كود :
Public connString As String = "connection string"

Private Sub Button1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button1.Click
    Try

        Dim rtn As Integer

        Using cnn As New SqlConnection(connString)
            cnn.Open()

            Dim sql As String = _
                "INSERT INTO [table] ([col1], [col2], [col3] ) VALUES (@col1, @col2, @col3 ) "

            Using cmd As New SqlCommand(sql, cnn)
                cmd.Parameters.AddWithValue("@col1", TextBox1.Text.Trim)
                cmd.Parameters.AddWithValue("@col2", CheckBox1.Checked)
                cmd.Parameters.AddWithValue("@col3", DateTimePicker1.Value.Date)

                rtn = cmd.ExecuteNonQuery

            End Using

            cnn.Close()
        End Using

        If rtn > 0 Then
            MsgBox("Inserted.")
        End If

    Catch ex As Exception
        MsgBox(ex.Message)
    End Try
End Sub

UPDATE
كود :
Public connString As String = "connection string"

Private Sub Button1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button1.Click
    Try

        Dim rtn As Integer

        Using cnn As New SqlConnection(connString)
            cnn.Open()

            Using cmd As New SqlCommand("UPDATE [table] SET [col1]=@col1, [col2]=@col2, [col3]=@col3 ) WHERE [id]=@id", cnn)
                cmd.Parameters.AddWithValue("@col1", TextBox1.Text.Trim)
                cmd.Parameters.AddWithValue("@col2", CheckBox1.Checked)
                cmd.Parameters.AddWithValue("@col3", DateTimePicker1.Value.Date)
                cmd.Parameters.AddWithValue("@id", userid)

                rtn = cmd.ExecuteNonQuery

            End Using

            cnn.Close()
        End Using

        If rtn > 0 Then
            MsgBox("Updated.")
        End If

    Catch ex As Exception
        MsgBox(ex.Message)
    End Try
End Sub

DELETE
كود :
Public connString As String = "connection string"

Private Sub Button1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button1.Click
    Try

        Dim rtn As Integer

        Using cnn As New SqlConnection(connString)
            cnn.Open()

            Using cmd As New SqlCommand("DELETE FROM [table] [id]=@id", cnn)
                cmd.Parameters.AddWithValue("@id", userid)

                rtn = cmd.ExecuteNonQuery

            End Using

            cnn.Close()
        End Using

        If rtn > 0 Then
            MsgBox("Deleted.")
        End If

    Catch ex As Exception
        MsgBox(ex.Message)
    End Try
End Sub

موفقين

RE: استعلام بخصوص حقل date - djelloul - 17-08-15

تسلم أخي الكريم