مقارنة صورتين و الحصول علي الفرق بينهم Comparing Two Images and Get Diff Image

PHP كود :
       ' المرحلة الأولي

        ' تعريف الصورتان المراد المقارنة بينهما و الحصول منهما علي صورة توضح الفارق بين الصورتان
        Dim sourceBitmap As Bitmap = PictureBox2.Image
        Dim destBitmap As Bitmap = PictureBox1.Image


        ' المرحلة الثانية 

        ' الحصول علي مصفوفة البايت الخاصة بكل صورة أعلاه

        ' الحصول علي مصفوفة الأوان الخاصة بالصورة الأولي و هي عبارة عن مصفوفة بايت

        Dim sourceBitmapData As Imaging.BitmapData = sourceBitmap.LockBits(New Rectangle(0, 0, sourceBitmap.Width, sourceBitmap.Height), Imaging.ImageLockMode.ReadOnly, Imaging.PixelFormat.Format32bppArgb)
        Dim sourceBytes As Byte() = New Byte(sourceBitmapData.Stride * sourceBitmapData.Height - 1) {}
        Runtime.InteropServices.Marshal.Copy(sourceBitmapData.Scan0, SourceBytes, 0, SourceBytes.Length)
        sourceBitmap.UnlockBits(sourceBitmapData)

        ' الحصول علي مصفوفة الأوان الخاصة بالصورة الثانية و هي أيضا عبارة عن مصفوفة بايت

        Dim destBitmapData As Imaging.BitmapData = destBitmap.LockBits(New Rectangle(0, 0, destBitmap.Width, destBitmap.Height), Imaging.ImageLockMode.ReadOnly, Imaging.PixelFormat.Format32bppArgb)
        Dim destBytes As Byte() = New Byte(destBitmapData.Stride * destBitmapData.Height - 1) {}
        Runtime.InteropServices.Marshal.Copy(destBitmapData.Scan0, destBytes, 0, destBytes.Length)

        destBitmap.UnlockBits(destBitmapData)

        ' المرحلة الثالثة

        ' تعريف متغير يعبر عن مصفوفة الفروقات في الألوان
        ' وهذا المتغير عبارة عن مصفوفة بايت و السعة الخاصة بهذه المصفوفة تكون بنفس سعة اي من مصفوفات الصور أعلاه

        Dim diffBytes As Byte() = New Byte(sourceBytes.Length - 1) {}


        ' المرحلة الرابعة
        ' بناء الحلقة التكرارية التي نقارن فيها بين الألوان في الصور

        ' ملحوظة هامة
        ' الألوان في الصور يتم تخزينها في صورة
        ' RGBA: RED Green Blue Alpha

        Dim i As Integer = 0
        While i < sourceBytes.Length - 1
            ' نحصل علي اللون من الصورة الأولي و نقارنه باللون في الصورة الثانية
            ' يجب أن لا  ننسي أن الألوان في الصور علي هيئة 
            ' RGBA: RED Green Blue Alpha
            If (sourceBytes(i) = destBytes(i)) AndAlso (sourceBytes(i + 1) = destBytes(i + 1)) AndAlso (sourceBytes(i + 2) = destBytes(i + 2)) AndAlso (sourceBytes(i + 3) = destBytes(i + 3)) Then
                ' تعريف لون بديل سنستخدمه لنملأ به مصفوفة الفروقات في حالة تساوي الأوان في الصورتان
                Dim clr As Color = Color.Magenta
                ' في حالة تساوي الوان البكسل في الصورتان نعبئ مصفوفة الفروقات بأي لون نحدده
                ' وهنا أنا اخترت اللون الماجنتا كلون بديل
                diffBytes(i) = CByte(clr.R)
                diffBytes(i + 1) = CByte(clr.G)
                diffBytes(i + 2) = CByte(clr.B)
                diffBytes(i + 3) = CByte(clr.A)

            Else
                '  في حالة اختلاف الالون بين الصورتان
                ' نقوم بتعبئة مصفوفة الفروقات باللون الموجود في الصورة الأصلية

                diffBytes(i) = sourceBytes(i)
                diffBytes(i + 1) = sourceBytes(i + 1)
                diffBytes(i + 2) = sourceBytes(i + 2)
                diffBytes(i + 3) = sourceBytes(i + 3)

            End If

            i += 4
        End While


        ' المرحلة الخامسة و الأخيرة 
        ' تحويل مصفوفة الفروقات الي صورة
        ' وهي تكون صورة نبنيها بنفس ابعاد اي من الصورتان التي نقارن بينهما

        Dim diffBitmp As New Bitmap(sourceBitmap.Width, sourceBitmap.Height)
        Dim data As Imaging.BitmapData = diffBitmp.LockBits(New Rectangle(0, 0, diffBitmp.Width, diffBitmp.Height), Imaging.ImageLockMode.WriteOnly, Imaging.PixelFormat.Format32bppArgb)
        ' نكتب مصفوفة الأوان باستخدام المارشال كلاس
        Runtime.InteropServices.Marshal.Copy(diffBytes, 0, data.Scan0, diffBytes.Length)
        diffBitmp.UnlockBits(data)

        ' أخيرا نقوم بعرض صورة الفروقات في بكتشر بوكس
        Me.PictureBox3.Image = diffBitmp