[مشروع] أداه TextBoxPlaceholder تسمح باظهار تلميح حول مربع النص عندما يكون فارغا

كود :
Imports System.ComponentModel



Public Class TextBoxPlaceholder

    Inherits TextBox





    Private m_Hint As String

    <Description("Specify The Text To Be Shawn as a Placeholder"),

    Category("Placeholder")>

    Public Property Hint As String

        Get

            Return m_Hint

        End Get

        Set(ByVal value As String)

            m_Hint = value

            Me.Invalidate()

        End Set

    End Property





    Private m_HideHintWhenFocused As Boolean = True

    <Description("Specify Wheather the hint will be hidden when the tool loses focus"),

    Category("Placeholder")>

    Public Property HideHintWhenFocused As Boolean

        Get

            Return m_HideHintWhenFocused

        End Get

        Set(ByVal value As Boolean)

            m_HideHintWhenFocused = value

            Me.Invalidate()

        End Set

    End Property





    Private m_HintColor As Color = SystemColors.GrayText

    <Description("Specify The Hint Color"),

    Category("Placeholder")>

    Public Property HintColor As Color

        Get

            Return m_HintColor

        End Get

        Set(ByVal value As Color)

            m_HintColor = value

            Me.Invalidate()

        End Set

    End Property

    Protected Overrides Sub WndProc(ByRef m As Message)

        MyBase.WndProc(m)



        If m.Msg = &HF Then

            If Not (Focused AndAlso HideHintWhenFocused) _

                AndAlso String.IsNullOrEmpty(Me.Text) _

                AndAlso Not String.IsNullOrEmpty(Me.Hint) Then

                Using g = Me.CreateGraphics()

                    TextRenderer.DrawText(g, Me.Hint, Me.Font, Me.ClientRectangle, HintColor, Me.BackColor,

                        TextFormatFlags.Top Or If(RightToLeft, TextFormatFlags.RightToLeft Or TextFormatFlags.Right, TextFormatFlags.Left))

                End Using

            End If

        End If

    End Sub



    Protected Overrides Sub OnTextChanged(e As EventArgs)

        MyBase.OnTextChanged(e)

        If String.IsNullOrEmpty(Me.Text) AndAlso Not HideHintWhenFocused Then

            Invalidate()

        End If

    End Sub

End Class