ما هو كود معرفة نوع البيانات من اكسس؟

PHP كود :

 Private Sub get_Cols(tb As String)
      dgvcols.Rows.Clear()
      If con.State = ConnectionState.Closed Then con.Open()
      Dim dt As DataTable = con.GetOleDbSchemaTable(OleDbSchemaGuid.Columns, New Object() {Nothing, Nothing, tb, Nothing})
      If dt.Rows.Count = 0 Then
          MsgBox(" لا توجد حقول!", MsgBoxStyle.Exclamation, "")
          Exit Sub
      End If
      For i As Integer = 0 To dt.Rows.Count - 1
          dgvcols.Rows.Add(dt.Rows(i).Item("Column_Name"), dt.Rows(i).Item("Data_Type").ToString)
      Next
  End Sub

PHP كود :

Public Function getcols(cn As OleDbConnection, tb As String) As DataTable
     If cn.State = ConnectionState.Closed Then cn.Open()
     adb.Clear()
     adb.Columns.Clear()
     adb.Rows.Clear()
     Using cm As New OleDbCommand("", cn)
         cm.CommandText = "select top 1 * from " & tb
         adb.Load(cm.ExecuteReader)
     End Using
     Return adb
 End Function

PHP كود :

           Dim dt As New DataTable
            dt = getcols(con, ListBox1.Text)
            ListBox2.Items.Clear()
            For Each dc As DataColumn In dt.Columns
                ListBox2.Items.Add(dc.ColumnName)
                txtcode.AppendText(dc.ColumnName & vbTab & dc.DataType.Name & vbNewLine)
            Next

PHP كود :

Private Sub get_Cols(tb As String)
    dgvcols.Rows.Clear()
    If con.State = ConnectionState.Closed Then con.Open()

    Dim dt As DataTable = con.GetOleDbSchemaTable(OleDbSchemaGuid.Columns, New Object() {Nothing, Nothing, tb, Nothing})

    If dt.Rows.Count = 0 Then
        MsgBox("لا توجد حقول!", MsgBoxStyle.Exclamation, "")
        Exit Sub
    End If

    For i As Integer = 0 To dt.Rows.Count - 1
        Dim columnName As String = dt.Rows(i).Item("COLUMN_NAME").ToString()
        Dim dataType As Integer = Convert.ToInt32(dt.Rows(i).Item("DATA_TYPE"))
        Dim dataTypeName As String = GetDataTypeName(dataType)
        dgvcols.Rows.Add(columnName, dataTypeName)
    Next

    con.Close()
End Sub

Private Function GetDataTypeName(dataType As Integer) As String
    Select Case dataType
        Case 3
            Return "Long Integer"
        Case 4
            Return "Single"
        Case 5
            Return "Double"
        Case 6
            Return "Currency"
        Case 7
            Return "Date/Time"
        Case 11
            Return "Boolean"
        Case 17
            Return "Byte"
        Case 72
            Return "GUID"
        Case 130
            Return "Text"
        Case 131
            Return "Decimal"
        Case Else
            Return "Other"
    End Select
End Function