[ali.alfoly]

راجع الاداة دي هتعجبك

كود :

#Region "   التحقق من وجود انترنت على الجهاز   "


    Public Class Check

        '- اداة التحقق الخفي
        Private WithEvents BackgroundWorker_Check_Net As New ComponentModel.BackgroundWorker

        ''' <summary>صب ابدء التحقق</summary>
        Public Sub Set_Check()
            If Not (Me.BackgroundWorker_Check_Net.IsBusy) Then
                '- بدء التحقق الخفي
                Me.BackgroundWorker_Check_Net.RunWorkerAsync()
            End If
        End Sub

        ''' <summary>حدث الانتهاء من التحقق</summary>
        Public Event Check_Complete(ByVal sender As Object, ByVal e As Boolean)

        '- بدء التحقق الخفي
        Private Sub BackgroundWorker1_DoWork(sender As Object, e As ComponentModel.DoWorkEventArgs) Handles BackgroundWorker_Check_Net.DoWork
            'System.Threading.Thread.Sleep(5000)
            Try
                If (Not My.Computer.Network.IsAvailable) OrElse _
                   (Not My.Computer.Network.Ping("www.google.com", 10000)) Then
                    e.Cancel = True
                    Exit Sub 'انهاء
                End If
            Catch ex As Exception
                e.Cancel = True
                Exit Sub 'انهاء
            End Try

        End Sub

        '- عند الانتهاء من التحقق
        Private Sub BackgroundWorker1_RunWorkerCompleted(sender As Object, e As ComponentModel.RunWorkerCompletedEventArgs) Handles BackgroundWorker_Check_Net.RunWorkerCompleted

            If (Not (e.Error Is Nothing)) OrElse e.Cancelled Then
                '- تفجير الحدث
                RaiseEvent Check_Complete(Me, False)
            Else
                '- تفجير الحدث
                RaiseEvent Check_Complete(Me, True)
            End If

        End Sub

    End Class



#End Region