[n.kadum]

(16-10-18, 10:19 AM)rnmr كتب : جرب هذا

كود :

Imports System.Data.OleDb

Public Class Form1

   Dim con As New OleDbConnection("Provider=Microsoft.ACE.OLEDB.12.0;Data Source=DB1.accdb")
   Dim DA As New OleDbDataAdapter("SELECT * FROM [information]", con)
   Dim DT As New DataTable


   Sub sava()

       ' تحديث قاعدة البيانات
       Dim SA As New OleDbCommandBuilder(DA)
       SA.QuotePrefix = ("[")
       SA.QuoteSuffix = ("]")
       DA.Update(DT)
       DT.AcceptChanges()

       ' إعادة تعبئة الداتاجريدفيو
       DT.Clear()
       DA.Fill(DT)
       DG1.DataSource = DT

       ' إظهار السطر المضاف أخيراً
       DG1.ClearSelection()
       DG1.FirstDisplayedScrollingRowIndex = DG1.Rows.Count - 1
       DG1.Rows(DG1.Rows.Count - 1).Cells(0).Selected = True
   End Sub

   Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
       ' إعادة تعبئة الداتاجريدفيو
       DA.Fill(DT)
       DG1.DataSource = DT
   End Sub

   Private Sub Button1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button1.Click

       ' التأكد من إدخال بيانات رقم الكتاب
       If Not IsNumeric(TextBox1.Text) Then
           MessageBox.Show("ادخل رقم الكتاب من فضلك")
           TextBox1.Focus()
           Return
       End If

       ' التأكد من إدخال بيانات الموضوع
       If TextBox2.Text.Trim = "" Then
           MessageBox.Show("ادخل الموضوع من فضلك")
           TextBox2.Focus()
           Return
       End If

       ' التأكد من إدخال بيانات الجهة الصادر منها
       If TextBox3.Text.Trim = "" Then
           MessageBox.Show("ادخل الجهة الصادر منها من فضلك")
           TextBox3.Focus()
           Return
       End If

       ' التأكد من إدخال بيانات اضبارة الحفظ
       If TextBox4.Text.Trim = "" Then
           MessageBox.Show("ادخل اضبارة الحفظ من فضلك")
           TextBox4.Focus()
           Return
       End If

       Try

           ' فتح الإتصال إذا لم يكن مفتوحات=
           If con.State <> ConnectionState.Open Then con.Open()

           ' التأكد من وجود رقم الكتاب مسبقا
           Dim cmd As New OleDbCommand("SELECT COUNT([NumBook]) FROM [information]  WHERE [NumBook]=? ", con)
           cmd.Parameters.AddWithValue("@", Val(TextBox1.Text))
           If cmd.ExecuteScalar > 0 Then
               ' رقم الكتاب موجود مسبقا
               MsgBox("record exists!", MsgBoxStyle.Exclamation, "Add New User!")
               Return
           End If

           ' إضافة البيانات الجديدة
           Dim row As DataRow = DT.NewRow
           row.Item(1) = DateTimePicker1.Value.ToString("dd/MM/yyyy")
           row.Item(2) = TextBox1.Text
           row.Item(3) = DateTimePicker2.Value.ToString("dd/MM/yyyy")
           row.Item(4) = TextBox2.Text
           row.Item(5) = TextBox3.Text
           row.Item(6) = TextBox4.Text
           row.Item(7) = TextBox5.Text
           DT.Rows.Add(row)

           ' حفظ الكتاب الجديد
           sava()
           MessageBox.Show("تم الحفظ بنجاح")

           ' إفراغ الأدوات لإضافة جديدة
           For Each c As Control In Controls
               If TypeOf c Is TextBox Then c.Text = ""
           Next

           ' نقل التحكم إلى رقم الكتاب
           TextBox1.Focus()

       Catch ex As Exception
           ' عرض رسالة الخطأ
           MessageBox.Show(ex.Message)
       Finally
           ' إغلاق الإتصال
           con.Close()
       End Try

   End Sub

End Class

تسلم اخي العزيز الكود شغال والحمد لله كان عندي اشوية اخطاء ممنتبه عليهن والحمد لله انت صححتلي الموضوع مرة اخرى مشكور