[vbnet]

.....

راح أعطيك "بداية برمجة" في البحث والاستبدال داخل ملف الوورد

إعمل مشروع جديد

في Form1:
ضع ثلاث TextBox
إثنان Button


أضف المرجع الخاص بالوورد:
من القائمة Project إختر ...Add Reference
من النافذة التي ستظهر إختر التبويب [COM] ومنه إختر المكتبة Microsoft Word xx.0 Object Library أكبر رقم لديك


ضع هذا الكود في Form1

كود :

' أضف المرجع التالي من القائمة
' Project>Add Reference: [COM]> Microsoft Word xx.0 Object Library

Imports Microsoft.Office.Interop

Public Class Form1

    Private Sub Button1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button1.Click
        Using op As New OpenFileDialog
            op.Filter = "Word documents (*.docx,*.doc)|*.docx;*.doc"
            If op.ShowDialog = Windows.Forms.DialogResult.OK Then
                Me.TextBox1.Text = op.FileName
            End If
        End Using
    End Sub


    Private Sub Button2_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button2.Click
        If Me.TextBox1.Text <> "" Then
            If TextBox2.Text = "" Or Me.TextBox3.Text = "" Then
                MsgBox("يجب كتابة كلمة البحث وكلمة الاستبدال")
            Else
                WordFindAndReplace(Me.TextBox1.Text, Me.TextBox2.Text, Me.TextBox3.Text)
            End If
        End If
    End Sub

    Public Sub WordFindAndReplace(ByVal docFilename As String, ByVal findStr As String, ByVal replaceStr As String)
        Try

            Dim objWordApp As New Word.Application

            objWordApp.Visible = True ' إظهار برنامج الوورد
            ' True بدلا من False إذا أدرت عدم إظهار الوورد ضع

            ' فتح ملف الوورد
            Dim objDoc As Word.Document = objWordApp.Documents.Open(docFilename)
            objDoc = objWordApp.ActiveDocument

            ' wdReplaceAll بحث واستبدال نص للكل
            Dim result As Boolean = objDoc.Content.Find.Execute(FindText:=findStr, ReplaceWith:=replaceStr, Replace:=Word.WdReplace.wdReplaceAll)

            ' حفظ ملف الوورد
            objDoc.Save()
            objDoc.Close()
            objDoc = Nothing
            objWordApp.Quit()
            objWordApp = Nothing

            If Not result Then
                MsgBox("لم أجد مطابقة في البحث")
            Else
                MsgBox("تم الاستبدال بنجاح")
            End If

        Catch ex As Exception
            MsgBox(ex.Message)
        End Try
    End Sub

End Class

.....