[Ahmed jroup]

هل يمكن برمجة التشفير بطريقة قيصر بدون استخدام المصفوفة ؟؟

[silverlight]

راجع الرابط التالي

اللينك

تحديدا الأسلوب السادس
الذي عليك أن تحلطه مع الأسلوب الرابع

[Ahmed jroup]

شكرا أخي   

و لو يوجد أشياء أدوات أخرى ممكن ترسلها

[silverlight]

للتشفيير و فك التشفيير بطريقة قيصر
يمكنك استخدام الداول التالية

PHP كود :

   Private Function EncryptChar(chr As Char, shift As Integer) As Char
        If Not Char.IsLetter(chr) Then
            Return chr
        End If
        Dim i As Integer = Convert.ToInt32(If(Char.IsUpper(chr), "A"c, "a"c))
        Return ChrW((((Convert.ToInt32(chr) + shift) - i) Mod 26) + i)
    End Function

    Private Function Encrypt(s As String, shift As Integer) As String
        Dim result As String = String.Empty
        Dim i As Integer = 0
        While i < s.Length
            result += EncryptChar(s(i), shift)
            i += 1
        End While
        Return result
    End Function

    Private Function Decrypt(s As String, shift As Integer) As String
        Return Encrypt(s, 26 - shift)
    End Function 


كيفية إستخدام الدوال

PHP كود :

       Label1.Text = Encrypt("Visual Basic", 5)
        Label2.Text = Decrypt(Label1.Text, 5) 


طريقة أخري مشابهة لطريقة قيصر
ستجدها في الكلاس التالي

PHP كود :

Public Class Obfuscation

    Private _source As String
    Private _dest As String
    Private _valid As Integer
    Private _protection As String

    Public Sub New(source As String)
        Me.New(source, String.Empty)
    End Sub

    Public Sub New(source As String, protection As String)
        Me._source = source
        Me._valid = If(Not String.IsNullOrEmpty(source), 1, 0)
        Me._protection = protection
    End Sub

    Public ReadOnly Property Text As String
        Get
            Me.Obfuscate()
            Return _dest
        End Get
    End Property

    Private Sub Obfuscate()
        If Me._valid Then
            Dim chars As Char() = New Char(Me._source.Length - 1) {}
            Dim i As Integer = 0
            While i < Me._source.Length
                chars(i) = ChrW(AscW(Me._source(i)) Xor AscW(Me._protection(i Mod Me._protection.Length)))
                i += 1
            End While
            Me._dest = New String(chars)
        End If
    End Sub

End Class 


كيفية استخدام الكلاس

PHP كود :

       Label1.Text = New Obfuscation("Visual Basic 4 Arab", "1234567").Text
        Label2.Text = New Obfuscation(Label1.Text, "1234567").Text