[مبرمج مصرى]

بسم الله الرحمن الرحيم
الكود التالى يقوم بإنشاء قا عدة بيانات فى المسار
"d:\phone.mdb"
وذلك عن طريق
dao refrence
و بكلمة مرور هى
jit
ولكن كيف أترجم نفس الكود إلى الاصدارات الحديثة من فيجوال بيزيك دوت نت أى (تصميم قاعدة البيانات بالكود) ؟

Private Sub Form_Load()
Dim NewDb As Database, NewWS As WORKSPACE
Dim NewTbl As tabledef
Dim F1, F2, F3 As Field
Set NewWS = dbengine.workspaces(0)
Set NewDb = NewWS.createdatabase("d:\phone.mdb" _
, dblanggeneral & ";pwd=jit", dbencrypt)
Set NewTbl = NewDb.createtabledef("PhoneBook")
Set F1 = NewTbl.createfield("Name", dbtext)
Set F2 = NewTbl.createfield("Phone_Number", _
dbtext)
Set F3 = NewTbl.createfield("Address", dbtext)
NewTbl.fields.append F1
NewTbl.fields.append F2
NewTbl.fields.append F3
NewDb.TableDefs.append NewTbl
NewDb.Close

End Sub

[a.ahmed]

PHP كود :

Public Class Form1

    Dim cnnString As String = "Provider=Microsoft.Jet.OLEDB.4.0; Data Source=d:\phone.mdb;Jet OLEDB:Database Password=jit"
    Dim cnn As New OleDb.OleDbConnection(cnnString)

    Private Sub Button1_Click(ByVal sender As Object, ByVal e As EventArgs) Handles Button1.Click
        'Reference(COM): Microsoft ADO Ext. 6.0 for DDL and Security '
        Dim cat As New ADOX.Catalog()
        cat.Create(cnnString)
    End Sub

    Private Sub Button2_Click(ByVal sender As Object, ByVal e As EventArgs) Handles Button2.Click
        'Recommend: ID (PRIMARY KEY) '
        Dim sql As String = _
              "CREATE TABLE PhoneBook                   " & _
              "  (                                      " & _
              "     ID            COUNTER PRIMARY KEY,  " & _
              "     Name          VARCHAR,              " & _
              "     Phone_Number  VARCHAR,              " & _
              "     Address       VARCHAR               " & _
              "  );                                     "
        Dim cmd As New OleDb.OleDbCommand(sql, cnn)
        If cnn.State <> ConnectionState.Open Then cnn.Open()
        cmd.ExecuteNonQuery()
        cnn.Close()
    End Sub

    Private Sub Button3_Click(ByVal sender As Object, ByVal e As EventArgs) Handles Button3.Click
        Dim sql As String = _
            "INSERT INTO [PhoneBook] ( Name, Phone_Number, Address ) " & _
            "                 VALUES (@name,@phone_number,@address ) "
        Dim cmd As New OleDb.OleDbCommand(sql, cnn)
        cmd.Parameters.AddWithValue("@name", TextBox1.Text)
        cmd.Parameters.AddWithValue("@phone_number", TextBox2.Text)
        cmd.Parameters.AddWithValue("@address", TextBox3.Text)

        If cnn.State <> ConnectionState.Open Then cnn.Open()
        cmd.ExecuteNonQuery()
        cnn.Close()
    End Sub

End Class 


[مبرمج مصرى]

شكرا لهذا المجهود الرائع