[حامد محمد]

السلام عليكم

ازاي يا اخواني ان  اربط  درج المحاسبة بالبرنامج لدي لكي يفتح عند دفع المبلغ


او عند السداد عن طريق الشبكة (بطاقة البنك)  

[Ahmed_Mansoor]

وعليكم السلام ورحمة الله وبركاته

أهلا بك أخي الكريم , في البداية أيش نوع الكيبل الموصل من جهاز درج المحاسبه إلى الكمبيوتر هل USB أو COM وهل تم تعريف الجهاز في الكمبيوتر كطابعه , أو تقدر تبحث في قوقل عن هذا النص :
how to open cash drawer using vb6

[حامد محمد]

استسفار فقط  اخي احمد ..شكرا جزيلا و بارك الله فيك..


اهلا وسهلا بك اخي احمد افتقدناك تماما ...حفظك الله ورعاك

[Amir_Alzubidy]

اهلا بعودتك اخي الحبيب احمد منصور 
جئت اهلا و حللت سهلا 
حماك الله و حباك 
اهلا بك اخي الحبيب حامد 
بالنسبة لسؤالك حول كيفية فتح درج الكاش 
كما تفضل اخي احمد جزاه الله الجنة و والديه و من احبه بسؤالك عن كيفية ربط الطابعة 
و هذا يعني ان هناك اوامر سيتم ارسالها مباشرة من خلال البرنامج الى تلك المنافذ . 
استخدمت في برنامجي المحاسبي طريقة تمت تجربتها و هي تعمل بشكل جيد 
سأضع لك الكود في الاسفل باذن الله بعد ان اشرح لك الطريقة 
و عتبي على الاخوة الذين يقرأون الاسئلة و لديهم الحلول ولا يتفضلوا بالاجابة يؤسفني ذلك ، 
على كل حال 
ينبغي ان يكون في شاشة البيع قائمة منسدلة لقراءة اسماء الطابعات المتصلة 
حتى تتمكن من تعيين احداها كـ طابعة افتراضية ، بحيث يتم استقبال الامر المكتوب في الاسفل 
و هذا الكود كما تراه ، يمكنك تجربته و ان بدا لك خطب ما ابلغنا عنه ، بالتوفيق 

يضاف هذا الكود في قسم التصريحات 

PHP كود :

Option Explicit

Private Type DOCINFO
pDocName As String
pOutputFile As String
pDatatype As String
End Type

Private Declare Function ClosePrinter Lib "winspool.drv" (ByVal hPrinter As Long) As Long
Private Declare Function EndDocPrinter Lib "winspool.drv" (ByVal hPrinter As Long) As Long
Private Declare Function EndPagePrinter Lib "winspool.drv" (ByVal hPrinter As Long) As Long
Private Declare Function OpenPrinter Lib "winspool.drv" Alias "OpenPrinterA" (ByVal pPrinterName As String, phPrinter As Long, ByVal pDefault As Long) As Long
Private Declare Function StartDocPrinter Lib "winspool.drv" Alias "StartDocPrinterA" (ByVal hPrinter As Long, ByVal Level As Long, pDocInfo As DOCINFO) As Long
Private Declare Function StartPagePrinter Lib "winspool.drv" (ByVal hPrinter As Long) As Long
Private Declare Function WritePrinter Lib "winspool.drv" (ByVal hPrinter As Long, pBuf As Any, ByVal cdBuf As Long, pcWritten As Long) As Long 


هذا كود زر الامر فتح درج الكاش 

PHP كود :

Private Sub Open_cash_Click()

On Error Resume Next: Err.Clear
Dim myStr As String
myStr = Chr$(27) & "p" & Chr$(0) & Chr$(250) & Chr$(250)

Call sendToPrn(myStr)

End Sub

Private Sub sendToPrn(outString As String)

Dim lhPrinter As Long
Dim lReturn As Long
Dim lpcWritten As Long
Dim lDoc As Long
Dim sWrittenData As String
Dim printdata As String
Dim MyDocInfo As DOCINFO

Dim x As Printer
For Each x In Printers
If Left(x.DeviceName, 5) = Combo3.Text Then
Set Printer = x
Exit For
End If
Next

' Combo3.Text اسم الطابعة التي تم تعيينها كـ طابعة افتراضية

printdata = outString

lReturn = OpenPrinter(Printer.DeviceName, lhPrinter, 0)

If lReturn = 0 Then
MsgBox "The Printer Name not recognized."
Exit Sub
End If

MyDocInfo.pDocName = "SAMPLE"
MyDocInfo.pOutputFile = vbNullString
MyDocInfo.pDatatype = vbNullString
lDoc = StartDocPrinter(lhPrinter, 1, MyDocInfo)
Call StartPagePrinter(lhPrinter)
lReturn = WritePrinter(lhPrinter, ByVal printdata, Len(printdata), lpcWritten)
lReturn = EndPagePrinter(lhPrinter)
lReturn = EndDocPrinter(lhPrinter)
lReturn = ClosePrinter(lhPrinter)
End Sub 


[Ahmed_Mansoor]

أهلا بك أخي العزيز أمير بارك الله فيك وجزاك الله كل خير شكراً جزيلاً لك على كلماتك ودعواتك الطيبه الله يتقبل إن شاء الله لي ولك ولجميع المسلمين اللهم آمين ، بالنسبه لإستفسار الأخ الكريم فعلا شاهدت نفس كود أخوي أمير عند البحث في قوقل عن الموضوع أرجو أن يعمل الكود عند الأخ السائل والكود صراحه مهم لبرامج المحاسبيه لو يوضع في قسم مكتبة الأكواد ليكون مرجع يكون أفضل ، يعطيكم العافيه .

[Amir_Alzubidy]

السلام عليكم و رحمة الله 

بارك الله فيك اخوي احمد 

اسف على التاخير في الرد بسبب انقطاع النت المتواصل 

وضعت مثال في موضوع خاص لطريقة فتح درج الكاش 

حتى يكون مرجعاً لمن يبحث عنه

open cash drawer vb6