[Mahmoud41]

بسم الله الرحمن الرحيم

---

---

اوكي سؤالى بسيط جدا و مباشر 







اول شئ ابغي لما اختار صورة ب استخدام OpenFileDialog  يتم فتح الصوره في picturebox .



و اسألكم اذا اقدر اسوي صوره دائرية في picturebox بحيث اي صوره تدخل من OpenFileDialog تصبح دائرية فورا.



وشكرا لكل من قرأ كلامي و انتظر منكم الافادة..... 

[trakktour]

(31-12-20, 03:08 AM)Mahmoud41 كتب :

بسم الله الرحمن الرحيم

---

---

اوكي سؤالى بسيط جدا و مباشر 







اول شئ ابغي لما اختار صورة ب استخدام OpenFileDialog  يتم فتح الصوره في picturebox .



و اسألكم اذا اقدر اسوي صوره دائرية في picturebox بحيث اي صوره تدخل من OpenFileDialog تصبح دائرية فورا.



وشكرا لكل من قرأ كلامي و انتظر منكم الافادة..... 

السلام عليكم
تفضل اخي الكريم

كود :

Imports System.Drawing.Drawing2D
Public Class Form1
   Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
       PictureBox1.SizeMode = PictureBoxSizeMode.StretchImage
   End Sub

   Private Sub Button1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button1.Click
       Using ofd As New OpenFileDialog
           ofd.Filter = "Image Files|*.jpg;*.png;*.bmp"
           ofd.Multiselect = False
           If ofd.ShowDialog = DialogResult.OK Then
               MakeRoundedImage(Image.FromFile(ofd.FileName), PictureBox1)
           End If
       End Using
   End Sub

   Private Sub MakeRoundedImage(ByVal Img As Image, ByVal PicBox As PictureBox)
       Using bm As New Bitmap(Img.Width, Img.Height)
           Using grx2 As Graphics = Graphics.FromImage(bm)
               grx2.SmoothingMode = SmoothingMode.AntiAlias
               Using tb As New TextureBrush(Img)
                   tb.TranslateTransform(0, 0)
                   Using gp As New GraphicsPath
                       gp.AddEllipse(0, 0, Img.Width, Img.Height)
                       grx2.FillPath(tb, gp)
                   End Using
               End Using
           End Using
           If PicBox.Image IsNot Nothing Then PicBox.Image.Dispose()
           PicBox.Image = New Bitmap(bm)
       End Using
   End Sub
End Class