[عبد الله]

السلام عليكم ورحمة الله وبركاته

تقبل الله منا ومنكم الأعمال وأعاننا الله وإياكم على صيام رمضان وقيامه وقيام ليلة القدر إيماناً واحتساباً اللهم ءامين.

لدي مشروع احتاج فيه لطريقة إضافة كنترول مثل wordpad ( الذي يأتي مع الويندوز ) بحيث اتحكم في النص من تلوين وحجم الخط وتوسيط وغيرها من التعديلات.

[الطالب]

سلام

استخدم RichTextBox1 ولو اني اتوقع انك تعرفها ولا تريدها

كود :

Public Class Form1

    ' عدم اخفا المحدد
    Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
        RichTextBox1.HideSelection = False
    End Sub

    ' تلوين
    Private Sub Button1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button1.Click
        Dim selColor As Color = Color.Red
        RichTextBox1.SelectionColor = selColor
    End Sub

    ' النمط
    Private Sub Button2_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button2.Click
        Dim _fontStyle As FontStyle = FontStyle.Bold + FontStyle.Italic
        RichTextBox1.SelectionFont = New Font(RichTextBox1.SelectionFont.FontFamily, RichTextBox1.SelectionFont.Size, _fontStyle)
    End Sub

    ' الحجم
    Private Sub Button3_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button3.Click
        Dim _fontSize As Single = 20
        RichTextBox1.SelectionFont = New Font(RichTextBox1.SelectionFont.FontFamily, _fontSize, RichTextBox1.SelectionFont.Style)
    End Sub

    ' الخط
    Private Sub Button4_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button4.Click
        Dim _fontName As String = "Courier New"
        RichTextBox1.SelectionFont = New Font(_fontName, RichTextBox1.SelectionFont.Size, RichTextBox1.SelectionFont.Style)
    End Sub

    ' المحاذاه
    Private Sub Button5_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button5.Click
        Dim _Alignment As String = HorizontalAlignment.Center
        RichTextBox1.SelectionAlignment = _Alignment
    End Sub

End Class

كوفقين

[عبد الله]

وعليكم السلام
على العكس أخي الطالب كنت أريد ما يفي بالغرض وابشرك أني وجدت هذا المثال الرائع
لمن أراد المثال هذا رابط المثال: http://3ixgfx32po625qmg71336d5w.wpengine...ordPad.rar

[الطالب]

سلام

هذه اضافه حفظ وقراء وتحديث محتوى ritchtextbox الموجود المثال اللي وضعه اخونا عبدالله
http://3ixgfx32po625qmg71336d5w.wpengine...ordPad.rar

اضف ثلاث ازارير واحد للحفظ والثان للقراء والثالث للتحديث
تجب وضع قاعدت بيانات اكسس فيها جدول wordpad وفيه حقلان الاول اسمه docname نوعه نص ويكون مفتاح لعدم السماح ياتكرار الاسماء والحقل الثاني اسمه rtf ونوعه مذكره

كود :

#Region " RichTextBox1 to Database "

    Private connectionString As String = "Provider=Microsoft.ACE.OLEDB.12.0;Data Source=Database1.accdb"
    Dim docName As String = ""

    Private Sub Button1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button1.Click
        Dim dn As String = InputBox("أدخل اسم المستند للحفظ")
        If dn.Trim <> "" Then
            docName = dn
            If InsertWordPadDocument(docName, RichTextBox1.Rtf) Then
                MsgBox("تم الحفظ")
            End If
        End If
    End Sub

    Private Sub Button2_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button2.Click
        Dim dn As String = InputBox("أدخل اسم المستند للعرض")
        If dn.Trim <> "" Then
            docName = dn
            RichTextBox1.Rtf = SelectWordPadDocument(docName)
        End If
    End Sub

    Private Sub Button3_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button3.Click
        If MsgBox("هل تريد تحديث المستند:" & docName, MsgBoxStyle.YesNo) = MsgBoxResult.Yes Then
            If UpdateWordPadDocument(docName, RichTextBox1.Rtf) Then
                MsgBox("تم التحديث")
            End If
        End If
    End Sub


    Private Function SelectWordPadDocument(ByVal docName As String) As String
        Using conn As New OleDb.OleDbConnection(connectionString)
            Using cmd As New OleDb.OleDbCommand("SELECT [rtf] FROM [wordpad] WHERE [docname]=@docName", conn)
                cmd.Parameters.AddWithValue("@docName", docName)
                conn.Open()
                Return cmd.ExecuteScalar
                conn.Close()
            End Using
        End Using
    End Function

    Private Function InsertWordPadDocument(ByVal docName As String, ByVal rtf As String) As Boolean
        Using conn As New OleDb.OleDbConnection(connectionString)
            Using cmd As New OleDb.OleDbCommand("INSERT INTO [wordpad] ( [docName], [rtf]) VALUES ( @docName, @rtf)", conn)
                cmd.Parameters.AddWithValue("@docName", docName)
                cmd.Parameters.AddWithValue("@rtf", rtf)
                conn.Open()
                Return If(cmd.ExecuteNonQuery > 0, True, False)
                conn.Close()
            End Using
        End Using
    End Function

    Private Function UpdateWordPadDocument(ByVal docName As String, ByVal rtf As String) As Boolean
        Using conn As New OleDb.OleDbConnection(connectionString)
            Using cmd As New OleDb.OleDbCommand("UPDATE [wordpad] SET [rtf]=@rtf WHERE [docName]=@docName", conn)
                cmd.Parameters.AddWithValue("@rtf", rtf)
                cmd.Parameters.AddWithValue("@docName", docName)
                conn.Open()
                Return If(cmd.ExecuteNonQuery > 0, True, False)
                conn.Close()
            End Using
        End Using
    End Function

#End Region

موفقين