[HASAN6.0]

السلام عليكم ورحمه الله



الرجاء المساعدة في كود يمكنه قراءة جزء من نص ووضعه داخل تكست مثلاً
ولكن النص كالتالي :
C:\Program Files\DVD Maker\DVDMaker.exe

PHP كود :

C:\Program Files\DVD Maker\DVDMaker.exe 


حيث ارغب بالحصول على ما بعد اشارة \ فقط ( DVDMaker.exe ) ولكم جزيل الشكر مسبقاً .

[ناجي إبراهيم]

السلام عليكم...

إذا كنت تقصد التعامل مع مسارات الملفات فإليك الدالتين التاليتين. ضعهما في Module لاستعمالهما على مستوى المشروع (من أي نافذة):

كود :

' دالة للحصول على اسم الملف و امتداده من مسار كامل
Public Function ExtractFileName(ByVal APath As String) As String
    Dim LastSlash As Long
    
    APath = Trim$(APath)
    If APath = "" Then
        ExtractFileName = ""
    Else
        LastSlash = InStrRev(APath, "\")
        If LastSlash = 0 Then
            ExtractFileName = APath
        Else
            ExtractFileName = Mid$(APath, LastSlash + 1)
        End If
    End If
End Function

' دالة للحصول على المسار فقط دون اسم الملف و امتداده
Public Function ExtractFilePath(ByVal APath As String) As String
    Dim LastSlash As Long
    
    APath = Trim$(APath)
    If APath = "" Then
        ExtractFilePath = ""
    Else
        LastSlash = InStrRev(APath, "\")
        If LastSlash = 0 Then
            ExtractFilePath = ""
        Else
            ExtractFilePath = Left$(APath, LastSlash - 1)
        End If
    End If
End Function

* مثلاً إذا فرضنا أن المسار الكامل (مثل C:\Program Files\DVD Maker\DVDMaker.exe) مكتوب في Text1 فإن الكود التالي يضع اسم الملف و امتداده (DVDMaker.exe) في Text2 و يضع المسار فقط (C:\Program Files\DVD Maker) في Text3:

كود :

Private Sub Command1_Click()
    Text2.Text = ExtractFileName(Text1.Text)
    Text3.Text = ExtractFilePath(Text1.Text)
End Sub

نرجو الاستفادة و السلام.