[مجاهد2010]

السلام عليكم ورحمة الله وبركاته

كيف اجعل الوينسوك تنتظر الاتصال علي اكثر من بورت في نفس الوقت ، بس البورتات موجودة في ليست بوكس

يعني عندي لليست بوكس فيه عدد من البورتات تحت بعضيها علي سبيل المثال
50
60
70
كيف اجعل الوينسوك تنتظر الاتصال علي كل هذه البورتات

يعني Listen هتساوي ايه ؟

Winsock1.Listen

بارك الله فيكم انتظر الاجابة من الاسود

[VB_Coder]

السلام عليكم

- أدرج أداة ونسوك وضع قيمة الخاصية Index تساوي صفر . ثم إستخدم هذا الكود :

كود :

Private Function Is_PortInUse(zPort As Long) As Boolean
On Error GoTo zER

Is_PortInUse = True

Winsock1(0).Close
DoEvents
Winsock1(0).LocalPort = zPort
DoEvents
Winsock1(0).Listen
DoEvents
Winsock1(0).Close
DoEvents

Is_PortInUse = False
Exit Function

zER:
   If Err.Number <> 0 Then
      Is_PortInUse = True
      Exit Function
   Else
      Err.Clear
   End If
  
End Function


Private Sub Form_Load()

If List1.ListCount > 0 Then

   Dim I As Integer
   Dim R As Integer
  
   For I = 0 To List1.ListCount - 1
      
       If Trim$(List1.List(I)) <> "" And IsNumeric(Trim$(List1.List(I))) = True Then
          
          If Is_PortInUse(Val(Trim$(List1.List(I)))) = False Then
             R = R + 1
             DoEvents
             Load Winsock1(R)
             DoEvents
             Winsock1(R).LocalPort = Val(Trim$(List1.List(I)))
             DoEvents
             Winsock1(R).Listen
             DoEvents
          End If
          
       End If
  
   Next
  
End If

End Sub


Private Sub Form_Unload(Cancel As Integer)

If Winsock1.Count > 1 Then

   Dim I As Integer
   Dim zCount As Integer
  
   zCount = Winsock1.Count - 1
  
   For I = 1 To zCount
       Unload Winsock1(I)
       DoEvents
   Next
  
End If

End Sub

[مجاهد2010]

بارك الله فيك ، وجزاك الله خير
ما شاء الله عليك مجهودك جبار في المنتدي

[algroob]

شكرررررررررررراً وانا محتاج هذا الكود