[أبو خالد الشكري]

السلام عليكم أيها المبرمجون ..

لو سمحتم مساعدتي في مشكلة برمجية لم أعرف حلها !
ما هو الكود الذي أحطه في الزر Button1 لكي يقرأ كود (رسالة التنبيه) الذي في TextBox1 ؟
 
أرفقت لكم التطبيق الذي فيه السؤال ، وهو بلغة VB.net
أرجو تحميله ليتضح لكم السؤال ؛ لتسهل عليكم الإجابة 

أنتظر ردكم الكريم ، وشكرًا .

[trakktour]

السلام عليكم أيها المبرمجون ..

لو سمحتم مساعدتي في مشكلة برمجية لم أعرف حلها !
ما هو الكود الذي أحطه في الزر Button1 لكي يقرأ كود (رسالة التنبيه) الذي في TextBox1 ؟
 
أرفقت لكم التطبيق الذي فيه السؤال ، وهو بلغة VB.net
أرجو تحميله ليتضح لكم السؤال ؛ لتسهل عليكم الإجابة 

أنتظر ردكم الكريم ، وشكرًا .

و عليكم السلام اخي 
تفضل

كود :

       Dim Code As String = TextBox1.Text
       TextBox2.Clear()
       Code = ("Imports System" & vbCrLf &
               "Imports System.Windows.Forms" & vbCrLf &
               "Imports Microsoft.Visualbasic" & vbCrLf &
               "Public Class TempClass" & vbCrLf &
               "Public Sub MyCode(ByVal Textbox2 As TextBox)" & vbCrLf &
               Code & vbCrLf &
               "End Sub" & vbCrLf &
               "End Class")
       Dim vbProv = New VBCodeProvider()
       Dim vbParams = New CompilerParameters()
       vbParams.ReferencedAssemblies.Add("System.dll")
       vbParams.ReferencedAssemblies.Add("System.Windows.Forms.dll")
       vbParams.ReferencedAssemblies.Add("Microsoft.VisualBasic.dll")
       vbParams.GenerateExecutable = False
       vbParams.GenerateInMemory = True
       vbParams.OutputAssembly = "MyCode"
       Dim compResults = vbProv.CompileAssemblyFromSource(vbParams, Code)
       If compResults.Errors.HasErrors Then
           Dim ErrorMsg As String = compResults.Errors.Count.ToString & " Errors:"
           For x As Integer = 0 To compResults.Errors.Count - 1
               ErrorMsg = ErrorMsg & vbCrLf & "Line: " & compResults.Errors(x).Line.ToString & " - " + compResults.Errors(x).ErrorText
           Next
           TextBox2.Text = ErrorMsg & vbCrLf & vbCrLf + Code
       Else
           Dim obj As Object = compResults.CompiledAssembly.CreateInstance("TempClass")
           Dim args() As Object = {Me.TextBox2}
           Try
               Dim result As Object = obj.GetType().InvokeMember("MyCode", BindingFlags.InvokeMethod, Nothing, obj, args)
           Catch Oops As Exception
               MessageBox.Show(Oops.Message)
           End Try
       End If

ضع هذا الكود في button
و اضف textbox اخر

و لا تنسى استدعاء المكتبات

كود :

Imports System.CodeDom.Compiler
Imports System.Reflection

[أبو خالد الشكري]

ما شاء الله عليك

أنت رائع جدا جدا

الكود شغال فعلا 100%

جزاك الله خيرًا ما قصرت بارك الله فيك .

واسمحني تعبتك في مساعدتي على الحصول على هذا الكود الرائع .

اشكرك من كل قلبي .

[trakktour]

ما شاء الله عليك

أنت رائع جدا جدا

الكود شغال فعلا 100%

جزاك الله خيرًا ما قصرت بارك الله فيك .

واسمحني تعبتك في مساعدتي على الحصول على هذا الكود الرائع .

اشكرك من كل قلبي .

تعبك راحة اخي الكريم
بتوفيق ان شاء الله