[أبو الحسن]

السلام عليكم ورحمة الله
كيف يمكنني تصميم شريط تقدم نفس هذا بالصورة المرفقة

[silverlight]

الكود أدناه عبارة عن Progress Indicator بسيط جدا و إن شاء الله يفي بإحتياجاتك.

كيف تستخدم الكود من داخل مشروعك:

1- افتح مشروع جديد ثم أضف الكود التالي له

2- قم بعمل build ثم اضف الكونترول الي الفورم

كود :

Imports System.Windows.Forms
Imports System.Drawing
Imports System.Drawing.Drawing2D

Namespace RiverNile

    '****************************************************************************************'
    ' Module Name:  RiverNile.Indicator
    ' Project:      ProgressIndicatorControl
    ' Copyright (c) RiverNile.Net.
    ' All other rights reserved. silverlight1212@yahoo.com
    ' The sample demonstrates how to buidl a simple progress indicator using backbufferd image
    '
    '
    ' This source is subject to the Public License.
    ' Follow my blog for future enhancement
    '
    '
    ' THIS CODE AND INFORMATION IS PROVIDED "AS IS" WITHOUT WARRANTY OF ANY KIND, EITHER
    ' EXPRESSED OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE IMPLIED WARRANTIES OF
    ' MERCHANTABILITY AND/OR FITNESS FOR A PARTICULAR PURPOSE.
    '****************************************************************************************'
    Public Class Indicator
        Inherits Control

        Private _value As Long
        Private _maximum As Long = 100

        Public Sub New()
            Me.Size = New Size(100, 100)
        End Sub

        Public Property Value() As Long
            Get
                Return _value
            End Get
            Set(value As Long)
                If value > _maximum Then value = _maximum
                _value = value
                Invalidate()
            End Set
        End Property

        Public Property Maximum As Long
            Get
                Return _maximum
            End Get
            Set(value As Long)
                If value < 1 Then value = 1
                _maximum = value
                Invalidate()
            End Set
        End Property

        ''' <summary>
        '''Not Applicaple, as buffered image will be handled by the code.
        ''' </summary>
        ''' <param name="pevent"></param>
        ''' <remarks></remarks>
        Protected Overrides Sub OnPaintBackground(pevent As PaintEventArgs)
            'MyBase.OnPaintBackground(pevent)
        End Sub

        Protected Overrides Sub OnPaint(e As PaintEventArgs)
            MyBase.OnPaint(e)

            BufferDrawing.DrawProgressIndicator(e.Graphics, Me.Width, Me.Height, ControlPaint.Dark(Me.BackColor), Me.BackColor, 2, Me._maximum, Me._value, Me.Font)
        End Sub

    End Class ' Indicator

    Public NotInheritable Class BufferDrawing

        Friend Shared Sub DrawProgressIndicator(gr As Graphics, imgWidth As Integer, _
                                     imgHeight As Integer, indicatorColor As Color, _
                                     indicatorBackcolor As Color, thick As Integer, _
                                     maxValue As Long, indicatorValue As Long, textFont As Font)


            Using bmp As New Bitmap(imgWidth, imgHeight)
                Using g As Graphics = Graphics.FromImage(bmp)
                    g.SmoothingMode = SmoothingMode.AntiAlias
                    g.SmoothingMode = SmoothingMode.HighQuality
                    g.Clear(indicatorBackcolor)

                    Using sb As New SolidBrush(indicatorColor)
                        Using indicatorPen As New Pen(sb, thick)
                            indicatorPen.StartCap = LineCap.Round
                            indicatorPen.EndCap = LineCap.Round
                            g.DrawArc(indicatorPen, CInt(thick / 2), CInt(thick / 2), imgWidth - thick - 1, imgHeight - thick - 1, 180, CInt((360 / maxValue) * indicatorValue))
                        End Using
                    End Using

                    Dim indicatorString As SizeF = g.MeasureString(CStr(CInt((100 / maxValue) * indicatorValue)), textFont)
                    g.DrawString(CStr(CInt((100 / maxValue) * indicatorValue)), textFont, Brushes.Black, CInt(imgWidth / 2 - indicatorString.Width / 2), CInt(imgHeight / 2 - indicatorString.Height / 2))
                    gr.DrawImage(bmp, 0, 0)
                End Using
            End Using

        End Sub

    End Class ' BufferDrawing

End Namespace ' RiverNile

3- اضف Timer الي الفورم ثم اكتب الكود بالشكل التالي

كود :

Public Class Form1
    Private Sub Timer1_Tick(sender As Object, e As EventArgs) Handles Timer1.Tick
        Indicator1.Value += 1
        Indicator1.Invalidate()
    End Sub

    Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
        Timer1.Enabled = True
        Timer1.Start()
    End Sub

End Class

[ali.alfoly]

لا يشترط ان يكون كل شئ اوبجكت او كنترول
التحايل في البرمجة اهم من البرمجة
ضع احدي هذه الصور وضع فوقها بنل به النسبة المؤية








اذا كنت تريد الصورة الخاصة بك تحديدا يمكن البحث عنها

[الشاكي لله]

(13-05-14, 04:46 PM)ali.alfoly كتب : لا يشترط ان يكون كل شئ اوبجكت او كنترول
التحايل في البرمجة اهم من البرمجة
ضع احدي هذه الصور وضع فوقها بنل به النسبة المؤية








اذا كنت تريد الصورة الخاصة بك تحديدا يمكن البحث عنها

ان كنت تريد High performance فالطريقة التي تستخدمها تثقل من عمل البرنامج وليست عملية .. استخدام الرسم احسن

[silverlight]

إقتباس :لا يشترط ان يكون كل شئ اوبجكت او كنترول
التحايل في البرمجة اهم من البرمجة
ضع احدي هذه الصور وضع فوقها بنل به النسبة المؤية

عفوا .....أخي الفاضل .......أختلف معك في موضوع أن التحايل في البرمجة أهم من البرمجة.
لا يوجد تحايل إطلاقا. الأمر عبارة عن ماذا تريد و كيف تريد أن تفعله؟.

و لدينا في مصر...مثلا شعبيا يقول.....كل شيخ و له طريقة...و المقصد هنا ..أن كل مبرمج و له أسلوبه

تقبل تحياتي

[ali.alfoly]

اخي محمد ما الدليل علي انها تثقل عمل البرنامج

اخي silverlight كلام جيد جدا ولا خلاف اصلا بين كلامي وكلامك انا فقط احببت ان اقول بدل ما اضيع وقت في صناعة اداة جلب الصورة من النت اسهل وكما قلت كل واحد له طريقة المهم ان نصل الي المطلوب

[aftfm]

اخي العزيز ali.alfoly

ممكن توضح اين اضع الكود الأول هل اضعة في Module ام في نفس الفورم
وما هي فائدة عمل puild

وهل احتاج الي صور واين اضعها

[الشاكي لله]

(14-05-14, 01:21 AM)ali.alfoly كتب : اخي محمد ما الدليل علي انها تثقل عمل البرنامج

اخي silverlight كلام جيد جدا ولا خلاف اصلا بين كلامي وكلامك انا فقط احببت ان اقول بدل ما اضيع وقت في صناعة اداة جلب الصورة من النت اسهل وكما قلت كل واحد له طريقة المهم ان نصل الي المطلوب

ههه والله ساعات احسك انك ماصار لك اسبوع ويا الدوت نت

طبيعي كثرة المكونات الموروثة من System.ComponentModel تزيد من ثقل البرنامج سواء عند التشغيل او عند استعمال البرنامج (لان استهلاك الرام = بطئ ااستجاب التطبيقات)

تبي مقارنة بالارقام بين كودك وكود لاخ silverlight ؟؟



المقارنة بين استعمال الرام (Memory Usage) :-







قد يبدو الفرق صغير فقط 100 كيلو بايت زيادة ، لكني لازلت لا اشجع على استخدام الpicture box كثيرا ، يعني انك تنشر 20 من picture box مع بانل + تايمر ، هذا بخلي برنامجك يزحف ..


بالنسبة لي لا احب ان اتحايل في البرمجة

احب كلشي يكون في موضعه

يعني ايام زمان ايام ماكنت ابرمج بلا حواس ، كنت استعمل الملفات النصية كقواعد بيانات
والسخيف في الموضوع ان كنت منظم الملفات على شكل ملفات xml


تدري كيف كنت اتعامل مع الملفات ؟؟؟

كنت اتعامل معاهم باطريقة التعامل مع المستندات العادية string.spilt ، filestream ، string.remove ، string.replace) والخرابيط هذي

تخيل ، في احد يستخدم دوال string مع مستندات xml !!!!

اتذكر كانت الاكواد طويييلة وكانت تأخذ وقت في التنفيذ ولكن كانت تعمل في النهاية


لكن الحين فهمت على الدنيا وصرت استخدم xmldocument , xmwriter وكل الكائنات الحلوة الي في سطرين تخليك تتعامل مع ملف xml وعناصره مثل الباشا


يعني كانت طريقتين تؤديان نفس الغرض الاولى تافهة وطويلة وتاخذ وقت اطول لكن كنت اجيد استخدام دوال string بشكل جيد جدا

ولكن لم اكن اجيد او اعرف ان هناك كائنات مباشرة تتعامل مع xmldocument فسويت حيلة دوال (string) الي كل ما اذكرها اضحك على نفسي (انا كنت اتحايل في البرمجة ولا اتحايل على نفسي) ههه


نفس الشي فكر في التقنيات والطرق المتطورة ، حتي لو كانت الطريقة تحتاج منك دراسة او فهم ، لأن ذلك سيصب بمصلحتك بالتأكيد

[silverlight]

الأخ الفاضل الشاكي لله....مشكور قوي علي محهودك و وقتك جزاك الله كل خير

الأخ الفاضل علي الفولي

الفكرة و بشكل عام إنه و عند بناء Library مهما كان نوعها ....هنا انت تقوم ب توفير وقت المبرمج مستقبلا...أيضا هذا الاسلوب يساعدك أو يساعد من يأتي من بعدك من مبرمجين علي تطوير هذا النوع من المكتبات

و مثال علي ذلك:

الكونترول هنا يمكن ان تضيف له صفات كثيرة و ممكن Animation يكون من خلال الكونترول نفسه......و علي فكرة عملية الرسم كلها تحدث علي صورة........و هذا اسهل الاساليب لبناء هذا النوع من الكونترول.
هناك أساليب اخري و هي انه يمكنك ان ترسم بشكل مباشر علي سطح الكونترول لكن هذا يحتاج الي وقت أطول و كود أكبر قليلا

كما قلت سابقا هي وجهات نظر و لك أن تفعل ما تراه صائبا لك.

أخي الفاضل اسمح لي اقول تعليق اخير:

نحن هنا لسنا ف سباق مع بعضنا البعض ...و ليس هدفنا ان نثبت من الأفضل.......بل نحن هنا جميعا لنتعلم من بعضنا البعض

و ربنا يوفقنا جميعا

[ali.alfoly]

جزاك الله خيرا اخي محمد علي هذا المجهود في التوضيح

توضيح
لم اقل ان التحايل وضع الشئ في غير موضعه
فقط ابحث عن البساطة والسهولة
وما الفرق بين picture box و Control من ناحية الذاكرة
وقلت سابقا انا فضلت وضع الصورة علي ان اقوم ببناء كنترول جديد فقط ليس الا

معلش طول بالك معي
اريد ان اعرف ما هذه الاداة التي عملت بها المقارنة


الاخ الكريم silverlight
فعلا كما تفضلت بتوضيح بناء Library ولاكن اذا استدعي الامر ذلك
وبخصوص التعليق الاخر هههههه انا هنا اتعلم فقط انتم اصحاب الفضل وانا مدين لكم بالكثير والكثير
اسئل الله تعالي ان يجعل ذلك في موازين حسناتكم