تقييم الموضوع :
  • 0 أصوات - بمعدل 0
  • 1
  • 2
  • 3
  • 4
  • 5
[VB.NET] التحقق من المدخلات النصية Textbox Validation - لبرنامج أكثر امانا
#1
Exclamation 
بسم الله الرحمن الرحيم
السلام عليكم ورحمة الله وبركاته اعضاء المنتدى الكرام

المقال بلغة C#

   

من المعروف ان غالبية البرامج تتعامل مع مدخلات نصية من المستخدم Textbox ،
ولكن المستخدم غير مضمون ، وبالتالي تضطر لاختبار المدخلات في كل مرة تريد تنفيذ شيء ما بناء عليها حتى لا يحصل exception اثناء تشغيل البرنامج ، وبالطبع عليك تتبع مدخلات المستخدم طوال الوقت ، وقد يحدث ان تنسى مربع نص بدون تتبع مدخلاته فينهار كل شيء

ماذا لو كان هناك طريقة فعالة لتحديد المدخلات المسموح بها لكل مربع نص مرة واحدة فقط ويتكفل البرنامج بالعراك مع المستخدم بدلا منك ؟

هناك بالفعل ما يسمى بالتحقق او Validation للادوات ، بحيث تكتب الكود الخاص التحقق من المدخل للاداه مرة واحدة فقط ، فتصبح الاداة منيعة ضد مدخلات المستخدم الغير متوقعة ، وما تشمله عملية التحقق من اظهار رسالة خطا او ما شابه.


مقادير الطبخة:

قبل ان نبدأ نحتاج ان تصنع مشروعا جديدا للتجربة ،
ومن ثم تضيف له :
  1. مربع نص TextBox لادخال الاسم ، قم بتسميته txtName
  2. مربع نص آخر TextBox لادخال البريد الالكتروني ، قم بتسميته txtEmail
  3. اداه مزود الاخطاء errorProvider لاظهار رسالة الخطأ دون ازعاع المسج بوكس ، دعها باسمها errorProvider1
  4. زر Button لادخال البيانات الى قاعدة البيانات مثلا ( لن اقوم بهذا فعلا ولكن للتجربة فقط )
طريقة التحضير:

الآن اصبح كل شيء جاهز لكتابة الكود 

أساس عملية التحقق هما الحدثان Validating و Validated


الحدث Validating: ينطلق عندما تبدأ عملية التحقق ويحدث ذلك عندما تفقد الاداه التركيز Focus عادة ، ويمكنك داخله اضافة الكود الخاص بالتحقق من المدخل اذا كان صالحا ام لا كما يلي :

وسيطة الحدث فيها خاصية e.Cancel من نوع bool ، اذا تم قمنا باسنادها ب true فاننا نخبر الحدث بان هذا المدخل غير صالح ، ويبقي على وضع تركيز الاداه

وبذلك يمكننا التأكد من صلاحية البيانات وفي حالة كانت غير صالة نقوم بجعل e.Cancel=true ونظهر رسالة خطأ مثلا ، والذي سيحدث بعد ذلك انه في كل مرة تحتاج الاداة للحقق من المدخل ستنظهر الى e.Cancel وبالتالي ستحدد ماعيها فعله،

في برنامجنا الصغير قم باضافة الحدث txtName.Validating من قائمة الاحداث ،
الان نريد ان نمنع المستخدم من ادخال قيمة اسم اقل من حرفين ، نضيف الكود التالي :

كود :
   Private Sub txtName_Validating(ByVal sender As Object, ByVal e As CancelEventArgs) Handles txtName.Validating
       Dim txt = DirectCast(sender, TextBox)

       If txt.Text.Trim().Length < 2 Then
           e.Cancel = True
           errorProvider1.SetError(txt, "الاسم لايمكن ان يكون اقل من حرفين")
       End If
   End Sub


الان شغل المشروع وحاول ان تكتب قيمة اصغر من حرفين وغادر الاداه ، تلاحظ ظهور خطأ يخبرك بانه عليك ادخال اسم اكبر من حرفين 


   


حسنا صديقي نحن الان في منتصف الطريق تقريبا

جرب ان تكتب قيمة اكبر من حرفين وانتقل الى المربع التالي ، نلاحظ انه ينتقل بدون مشاكل ولكن لم يتم ازالة الخطأ 
وهنا يأتي دور الحدث Validated 


الحدث Validated:
يتم اطلاقه بعد التأكد من صلاحية المدخلات في مربع النص ، 
يمكننا استخدامه لازالة علامة الخطأ 


كود :
   Private Sub txtName_Validated(ByVal sender As Object, ByVal e As EventArgs) Handles txtName.Validated
       Dim txt = DirectCast(sender, TextBox)
       errorProvider1.SetError(txt, "")
   End Sub


حسنا صديقي ، الان اصبح مربع النص آمن من المدخلات الغير مرغوب فيها

يمكنك ايضا التحقق من مدخلات المستخدم لتماشي نمط Regex معين ،
الكود التالي يجعل مربع البريد الالكتروني لايقبل الا صيغة بريد صحيحة :


كود :
   Private Sub txtEmail_Validating(ByVal sender As Object, ByVal e As CancelEventArgs) Handles txtEmail.Validating
       Dim txt = DirectCast(sender, TextBox)

       If Not Regex.IsMatch(txt.Text, "^[A-Za-z0-9._%+-]+@[A-Za-z0-9.-]+\.[A-Za-z]{2,}$") Then
           e.Cancel = True
           errorProvider1.SetError(txt, "صيغة بريد الكتروني غير صالحة")
       End If
   End Sub


وبنفس الطريقة :


كود :
   Private Sub txtEmail_Validated(ByVal sender As Object, ByVal e As EventArgs) Handles txtEmail.Validated
       Dim txt = DirectCast(sender, TextBox)
       errorProvider1.SetError(txt, "")
   End Sub



الآن ماذا نفعل عندما نريد التحقق من صلاحية جميع الادوات في الفورم جملة واحدة ؟ 
في زر اضافة لقاعدة البيانات مثلا نريد ان نتحقق من كافة المدخلات قبل ان تقع الفأس في الرأس وندخل لقاعدة البيانات بيانات فاسدة

هنا تظهر الدالة ValidateChildren() الخاصة بالفورم 

الدالة ValidateChildren :

دالة داخل الفورم تعيد قيمة من نوع bool تمثل هل كافة الادوات في الفورم تحتوي بيانات صالحة ام لا

وهي دالة عبقرية جدا ومفيدة جدا ، تخيل بسطر واحد تتحقق من مدخلات الفورم كله حتى وان احتوى على 600 حقل !  Big Grin 

الان الى التطبيق :

سنقوم باستدعاء ValidateChildren() واذا كانت النتيجة false نقوم ب return وبعد ذلك نكتب الاجراء الذي نريده فعلا من هذا الزر ، وبذلك نضمن ان الزر امن تماما

في حدث btnValidate.Click :


كود :
   Private Sub btnValidate_Click(ByVal sender As Object, ByVal e As EventArgs) Handles btnValidate.Click
       If Not Me.ValidateChildren() Then Return
       MessageBox.Show("جميع البيانات صالحة")
   End Sub


طيب كلام جميل الان شغل البرنامج واكتب مدخل سليم في خانة الاسم ، ثم اضغط تحقق 


   

تلاحظ ظهور خطأ ينبهنا الى ان ندخل بريد الكتروني 
اذا ادخلنا بريد الكتروني صالح وضغطنا الزر نجد الرسالة تظهر بدون مشاكل ورسالة الخطأ تختفي 


   

حسنا نحن انتهينا تقريبا 

ولكن ليس بعد، هناك بعض الخصائص التي نحدد بها سلوك عملية التحقق في الفورم الخاص بنا  :

AutoValidate: خاصية للفورم ، نحدد بها ما اذا اردنا ان يقوم الفورم بالتحقق تلقائيا او لا ، وتأخد قيمة من :


AutoValidate.Disable : لا نريد ان يقوم الفورم بالتحقق تلقائيا ، سنقوم به نحن ( مثلا اذا كنا سنستخدم ValidateChildren ولا نريد ازعاج المستخدم برسائل الخطأ)

AutoValidate.EnableAllowFocusChange : نريد ان يقوم الفورم بالتحقق من المدخلات تلقائيا ، ونريده ان يسمح للمستخدم بالتنقل بين المدخلات

AutoValidate.EnablePreventFocusChange (الافتراضية) : نريد ان يقوم الفورم بالتحقق من المدخلات تلقائيا ، ونريده ان يمنع للمستخدم من التنقل بين المدخلات


CausesValidation : خاصية للادوات من نوع bool ، تمثل هل الانتقال الى هذه الاداه يسبب اطلاق احداث التحقق من قيمة الاداه السابقة ؟

المثال في المرفقات 
اتمنى للجميع التوفيق
في رعاية الله


الملفات المرفقة
.zip   Validating TextBox VB.zip (الحجم : 60.53 ك ب / التحميلات : 30)
الرد
#2
Exclamation 
طيب الآن ما الخطوة التالية ؟

لاحظنا ان عملية اضافة احداث التحقق للمدخلات النصية والتعامل معها تتم بنفس الطريقة لمربعين النص تقريبا ، مع اختلاف شرط التحقق والرسالة التي تظهر للمستخدم ، 

تخيل ان عندك 5 مربعات نصية للمدخلات ( اسم ورقم تليفون وبريد الكتروني وقيمة المرتب وتاريخ التسجيل)  ، فان مطالب لكل مربع نص ان تضيف احداث validating و validated التي تقوم بنفس الشيء :

في البداية تتحقق من ان المدخل يوافق الشرط المعطى ، والا تلغي العملية وترسل رسالة خطأ ، واذا تم التحقق تكمل العملية وتمسح رسالة الخطأ

كود :
   Private Sub txtName_Validating(ByVal sender As Object, ByVal e As CancelEventArgs) Handles txtName.Validating
       Dim txt = DirectCast(sender, TextBox)

       If txt.Text.Trim().Length < 2 Then
           e.Cancel = True
           errorProvider1.SetError(txt, "الاسم لايمكن ان يكون اقل من حرفين")
       End If
   End Sub

   Private Sub txtName_Validated(ByVal sender As Object, ByVal e As EventArgs) Handles txtName.Validated
       Dim txt = DirectCast(sender, TextBox)
       errorProvider1.SetError(txt, "")
   End Sub


من غير المنطقي ان نكرر الكود كل مرة نضيف فيها مربع نص جديد ، انا شخصيا اكره تكرار الاكواد

ماذا اذا قمنا بتعريف اجراء عام لاي مربع نص يضيف هذه الاحداث ، ونخبره فقط بالشرط والرسالة ؟ فكره جيدة اليس كذلك ؟

كود :
   Sub AddValidation(textBox As TextBox, validationChecker As Func(Of String, Boolean), errorMsg As String)
       AddHandler textBox.Validating, Sub(s, e)
                                          Dim txt = DirectCast(s, TextBox)

                                          If Not validationChecker(txt.Text) Then
                                              e.Cancel = True
                                              errorProvider1.SetError(txt, errorMsg)
                                          End If
                                      End Sub

       AddHandler textBox.Validated, Sub(s, e)
                                         Dim txt = DirectCast(s, TextBox)
                                         errorProvider1.SetError(txt, "")
                                     End Sub
   End Sub



الاجراء يأخذ ثلاث مدخلات :
  1. مربع النص المراد اضافة احداث التحقق له
  2. دالة تمثل الشرط الذي يتم بناء عليه التحقق ( دالة عادية مدخلها string وتخرج bool ، او تعبير لمدا )
  3. رسالة الخطأ التي ستظهر في حالة عدم صلاحية البيانات
داخل الاجراء قمنا باضافة الاحداث كما في المشاركة الاولى في الموضوع باستخدام اضافة الاحداث اثناء التشغيل باستخدام تعابير لمدا

الان كل ما علينا فعله لاضافة احداث تحقق لاي مربع نص هو كتابة سطر واحد في المشيد او في حدث اللود للفورم :

للتحقق من الاسم اكبر من حرفين :
كود :
        AddValidation(txtName, Function(x) x.Trim().Length >= 2, "الاسم لايمكن ان يكون اقل من حرفين")
 
للتحقق من البريد الالكتروني :

كود :
       AddValidation(txtEmail, Function(x) Regex.IsMatch(x, "^[A-Za-z0-9._%+-]+@[A-Za-z0-9.-]+\.[A-Za-z]{2,}$"), "صيغة بريد الكتروني غير صالحة")


للتحقق من قيمة رقم عشري :

كود :
       Dim d As Double
       AddValidation(txtSalary, Function(x) Double.TryParse(x, d), "الرقم غير صالح")


وهكذا كلما اردت اضافة مربع نص اضف له سطر التحقق 
ويبقى استخدام ValidateChildren() كما هو ،
المثال بعد التعديل في المرفقات


الملفات المرفقة
.zip   Validating TextBox VB.zip (الحجم : 68.21 ك ب / التحميلات : 26)
الرد


المواضيع المحتمل أن تكون متشابهة .
الموضوع : الكاتب الردود : المشاهدات : آخر رد
  طريقة تقسيم كودك البرمجة الي سطرين أو أكثر كم تريد dametucorazon 1 1,187 06-09-19, 12:55 AM
آخر رد: سعود
  كيف تجعل برنامجك عالميا و يدعم أكثر من لغة silverlight 6 3,205 29-05-19, 10:32 PM
آخر رد: egbest2
  درس عمل باسورد لبرنامج بلغة Vb.net boty 4 2,597 17-10-18, 01:38 AM
آخر رد: اسامه الهرماوي
Exclamation [VB.NET] التعامل مع ال CMD عن طريق ال TextBox YousefOkasha 5 1,994 02-06-18, 09:34 PM
آخر رد: YousefOkasha
  [درس فيديو] مثال بسيط لبرنامج إجازات فقط لأغراض الشرح (الدرس الأول) عبدالله الدوسري 7 2,974 28-04-18, 06:55 PM
آخر رد: moniam
  [VB.NET] عايز كود مع الشرح لبرنامج اداره محل الإلكترونيات اسامه الهرماوي 1 1,037 25-02-18, 12:37 AM
آخر رد: sendbad100
  [مقال] إضافة خاصية التحجيم التلقائي - AutoSize - إلى أداة مربع النص - TextBox sooriaty03 9 6,071 11-02-16, 10:47 PM
آخر رد: العواد الصغير
  [VB.NET] تنسيق البينات بناء على المدخلات datagridview vb net فيديو أحمد النجار 0 1,771 24-01-15, 07:42 PM
آخر رد: أحمد النجار
  معلومة ::: Search In TextBox RaggiTech 1 1,378 06-10-12, 08:56 PM
آخر رد: RaggiTech
  كود- تكست بوكس شفاف Transparent TextBox RaggiTech 0 1,732 05-10-12, 01:44 PM
آخر رد: RaggiTech

التنقل السريع :


يقوم بقرائة الموضوع: بالاضافة الى ( 1 ) ضيف كريم